<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:spif="http://www.xmlspif.org/spif">
	<xsl:output method="xml" indent="yes"/>

	<xsl:template match="/spif:SPIF">
		<securityLabel xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:noNamespaceSchemaLocation="http://packages.trustedbird.org/securityLabel.xsd"><xsl:text>
	</xsl:text>
			<xsl:apply-templates select="spif:securityPolicyId" />
			<xsl:apply-templates select="spif:securityClassifications"/>
			<xsl:apply-templates select="spif:privacyMarks"/>
			<xsl:apply-templates select="spif:securityCategoryTagSets"/>
		</securityLabel>
	</xsl:template>
	
	<xsl:template match="spif:securityPolicyId">
		<securityPolicyIdentifier value="{@id}" label="{@name}"/><xsl:text>
</xsl:text>
	</xsl:template>
	
	<xsl:template match="spif:securityClassifications">
		<xsl:text>	</xsl:text><securityClassification valueDisplayed="true"><xsl:text>
</xsl:text>
			<xsl:apply-templates select="spif:securityClassification"/>
		<xsl:text>	</xsl:text></securityClassification><xsl:text>
</xsl:text>
	</xsl:template>	
	
	<xsl:template match="spif:securityClassification">
		<xsl:text>		</xsl:text><item value="{@lacv}" label="{@name}"/><xsl:text>
</xsl:text>
	</xsl:template>
	
	<xsl:template match="spif:privacyMarks">
		<xsl:text>	</xsl:text><privacyMarks freeText="true">
			<xsl:apply-templates select="spif:privacyMark"/>
		<xsl:text>	</xsl:text></privacyMarks>
	</xsl:template>	

	<xsl:template match="spif:privacyMark">
		<xsl:text>		</xsl:text><item value="{@name}"/>
	</xsl:template>	
	
	<xsl:template match="spif:securityCategoryTagSets">
		<xsl:text>	</xsl:text><securityCategories><xsl:text>
</xsl:text>
			<xsl:apply-templates select="spif:securityCategoryTagSet/spif:securityCategoryTag/spif:tagCategory"/>
		<xsl:text>	</xsl:text></securityCategories><xsl:text>
</xsl:text>
	</xsl:template>		
	
	<xsl:template match="spif:tagCategory">
		<xsl:variable name="oid" select="../../@id"/>
		<xsl:text>		</xsl:text><item oid="{$oid}" type="2" value="{@lacv}" label="{@name}"/><xsl:text>
</xsl:text>
	</xsl:template>
	
</xsl:stylesheet>

